//Check file for the ON paper available for referees
//we refer to a permutation representation for H from onsupp.mag

/*
load "D:\\Sporadic\\ON\\onsupp.mag";
load "D:\\magmadoc\\myccs.lib";   
load "D:\\magmadoc\\mygoldx.lib";
load "D:\\magmadoc\\Relation2Latex.mag";
load "D:\\Sporadic\\ON\\onCheck.mag";
*/

//Lemma 2.1
//we check that the given presentation leads to a subgroup isomorphic to the one given in onsupp.mag

    H1<r,s,c>:=Group<r,s,c|r^3 = s^16 = c^5 = (s *c^-1)^4 = (r*s^2 *r^-1
    *s^-1)^2= (r^-1*s^2*r*s^-1)^2 =s^-1*r^-1*c^-2*s^-1*r^-1*c*r*c^2 =
    (r^-1*c^-1*s^-1*c*s)^2 = r*c^2* r* s^-1* r^-1*s^-1*c^-2* r* c^-1=c*
    r^-1* s^-3* r^-1* c^-1* r^-1*s *c*r^-1=
    s* c^-1* s* r^-1* s* r^-1* c^-1* s*c^-1*r^-1*c=s^5*r^-1* c*r^-1* c^-1* s*c^-1 =
    s*r^-1*
    s^-1*c^-1*s*r^-1* s^-1*r*c*r^-1*c=c* s^2* c^-1* s* r^-1*c*r^-1* s*
    c* r =(r* s *r^-1* s^-1* r^-1* s^-1)^2 = (r^-1* s^-3* r^-1*
    s^-1)^2=s^2* r^-1*s^-1*r^-1*s^-1*r^-1*s^3*r^-1*s  =
    r^-1*c^-2*s*r^-1*s^-1*r^-1* s* c^-1* r^-1*s^-1*c=1>;
    
    subH1:= sub<H1|s*r^-1*c^2*s*r^-1*c^-1*r*c,c*s^-1*r^-1*c*s^-3*c>;
    PH:=CosetEnumerationProcess(H1,subH1: CosetLimit := 4000000,Print :=true);
    StartEnumeration(~PH);
    pH,Hb:=CosetAction(PH); 
  
    genh:=[rr,ss,cc];
    H:=sub<Sy|genh>;
    
    b,iso:=IsIsomorphic(H,Hb);//returns true, so we work with H instead of Hb
    
    H1<r,s,f>:=Group<r,s,f| r^3, (r * f)^3, (f^2 * r^-1)^2, f^5, (f * s)^4, (f * s^-1)^4, (s * r * s^-2 * r^-1)^2,
    s^-1 * f * r * f^-1 * r * s * r * f * r * f^-1, (s * r^-1 * s^-2 * r)^2, (s * f * s^-1 * f
    * r^-1)^2, s^3 * f * s^-4 * f * s, f * s * f^-2 * s^-1 * r * s * r^-1 * f^-1 * s^-1 * r,
    s^2 * r * s^-2 * r * s^2 * f * r^-1 * f^-1 >;
        
    
    
    //(a)
        ah:=AutomorphismGroup(H);
        pah,ahp:=PermutationRepresentation(ah);
        iah:=sub<ahp|[pah(g):g in InnerGenerators(ah)]>;
        inrr:=ah!hom<H->H|[<g,g^rr>:g in Generators(H)]>;
        Car:=Centralizer(ahp,pah(inrr));
        b,K:=HasComplement(Car,iah meet Car);
        ga:=K.1;        
        H1p<r,s,c>,fH1:=FPGroup(sub<H|genh>);
        
    //(b)
        [u@@fH1:u in [zz,tt,uu,zz2,tt2,uu2]];
        // [ (r * s * r * s^-1)^2, r * s^2 * r * s^2 * r * s^-2, (s * r)^4, (r^-1 * c^-1)^3, r^-1 * s^-1 * r * s^-1 * r^-1 * s^-2, (r^-1 * s^-1)^2 ]
        
        S:=sub<H|[ ss^-1 * rr * ss * rr, ss, ss^2 * rr^-1 * ss^-2 * rr * ss^-1 ]>;
        Index(H,S) mod 2;
        ZS:=Centre(S);
        ZS eq sub<S|zz>;
        (K.1@@pah)(S) eq S;        
        x2:=[zz2,tt2,uu2];
        x1:=[zz,tt,uu];
        [x2[i]^2 eq x1[i]:i in [1..3]];
        ss^8 eq zz;
        
    //(c)
        P:=pCore(H,2);
        P eq sub<H|zz2>;
        
    //(d)
        NS:=NormalSubgroups(S); 
        NS:=[x`subgroup:x in NS]; 
        EANS:=[x:x in NS|IsElementaryAbelian(x)];
        EANS8:=[x:x in EANS|#x eq 8];
        A:=EANS8[1];
        A eq sub<A|x1>;
    
    //(e)
        [#x:x in EANS];
        V:=EANS[2];
    
    //(f)
        CV:=Centralizer(H,V);
        CV eq Centralizer(S,V);
        V eq Centre(CV);
    
    //(g)
        S eq Normalizer(H,V);
    
    //(h)
        C:=Centralizer(H,A);
        C eq Centralizer(S,A);
        C eq sub<S|x2>;
        pC:=pCentralSeries(C,2);
        
    //(i)
        ANS:=[x:x in NS|IsAbelian(x)];
        [#x:x in ANS];// [ 1, 2, 4, 4, 4, 8, 8, 8, 16, 16, 16, 32, 64 ];
    
    //(j)
        gend:=[rr,ss];
        D:=sub<H|rr,ss>;
        D eq Normalizer(H,A);
        b,L:=HasComplement(D,C);
        not b;
        b:=IsIsomorphic(D/C,Sym(4));
        b;
        
    //(k)
        subh:=Subgroups(H);
        subhrep:=[x`subgroup:x in subh];
        cfr:=[x:x in subhrep|#Core(H,x) eq 1];
        m,pos:=Minimum([Index(H,x):x in cfr]);
        subH:=cfr[pos];
        subH:=sub<H| ss^2 * ff^-1 * rr * ss * rr^-1 * ff * ss * rr, rr * ss * rr * ff^-1 * ss * ff * ss^-2 >;        
        subH:= sub<H|ss*rr^-1*cc^2*ss*rr^-1*cc^-1*rr*cc,cc*ss^-1*rr^-1*cc*ss^-3*cc>;
        b:=IsIsomorphic(subH,Alt(6));
        
        
        
    //(l)
        kch:=LexLowestBaseConjugacyClassRepresentatives(sub<H|rr,ss,cc>);
        for p in PrimeDivisors(#H) do 
            InstallPrimePowermap(~kch,p);
        end for;
        Translate2LaTeX(kch, H, "H", "ON", ["r","s","c"], "D:\\Sporadic\\ON\\kch.tex");
        
    //(m)
        cth:=CharacterTable(H);
    
    //(n)
        AD:=AutomorphismGroup(D); 
        pad:=PermutationRepresentation(AD);
        ad:=Image(pad);
        iad:=sub<ad|[x@pad:x in InnerGenerators(AD)]>;// ad/iad IsElementaryAbelian of order 8
        b,K:=HasComplement(ad,iad);
        IsElementaryAbelian(K);
    
    //(o)
        kcd:=LexLowestBaseConjugacyClassRepresentatives(sub<D|rr,ss>);
        for p in PrimeDivisors(#D) do 
            InstallPrimePowermap(~kcd,p);
        end for;
        Translate2LaTeX(kcd, D, "D", "ON", ["r","s"], "D:\\Sporadic\\ON\\kcd.tex");
    
    //(p)
        ctd:=CharacterTable(D);
        
//Proposition 3.1
    //(a)
        ww:=rr*ss^-2*rr^2*ss;
        CHw:=Centralizer(H,ww);
        S1:=Centralizer(S,ww);
        K:=Complements(S1,sub<H|zz,ww>)[1];
        K2:=SylowSubgroup(K,2);
        bb:=K2.2;//s * r^-1 * s^-1 * r * s^-3 * r^-1
        K3:=SylowSubgroup(CHw,3);
        kk:=K3.1;
        K3 eq sub<K3|kk,kk^bb>;
        kk@@fH1;//s^-1 * c^-1 * r^-1 * s * r * c * r * c
        AS1:=AutomorphismGroup(S1);
        &and[S1@AS1.i eq S1:i in [1..Ngens(AS1)]];
        bb^2 in FrattiniSubgroup(S1);
    //(b)
        gene:=[rr1,ss1,gg];
        E:=sub<Sy1|rr1,ss1,gg>;
    
    //(c)
        DE:=sub<E|rr1,ss1>;
        gold:=#GoldSchmidtIndex(H,D,E,DE);
    
    //(d)
        Ef<r,s,g>,fE:=FPGroup(sub<E|rr1,ss1,gg>);
        E1<r,s,g>:=Group<r,s,g|r^3=s^16=g^3=r^-1*s^-1*r*s^-1*r^-1*
        s^-1*g^-1*s*g^-1=g*r^-1*g*s^-1*r^-1*g*s*r*s^-1=s^-2*g*s^-1*r^-1*s*r^-1*s^-1*g^-1=
        g^-1*s*r^-1*s*r^-1*s^-1*g*s^2=(s*r^-1*g^-1)^3=(r*s^2*r^-1*s^-1)^2>;
        pE1,E1p:=CosetAction(E1,sub<E1|g>);
        b:=IsIsomorphic(E,E1p);//true, so I keep working with E
    
    //(e)
        SE1:=Stabilizer(E,1);
        SE1 eq sub<SE1|SE1.1,SE1.2>;
        [x@@fE:x in [SE1.1,SE1.2]];
        //[ r^-1 * s * g * s^2 * r, s^3 * g^-1 * s^-1 * r * g^-1 ]
        
    //(f)
        kce:=LexLowestBaseConjugacyClassRepresentatives(sub<E|rr1,ss1,gg>);
        for p in PrimeDivisors(#E) do 
            InstallPrimePowermap(~kce,p);
        end for;
        Translate2LaTeX(kce, E, "N_G(A)", "ON", ["r","s","g"], "D:\\Sporadic\\ON\\kce.tex");
    
    //(g)      
        cte:=CharacterTable(E);

//Proposition 3.2
    //(b)
        isoDtoDE:=hom<D->DE|[<rr,rr1>,<ss,ss1>]>;
        MatchHwD:=<[ConjClassRepToClassName(kch,x),ConjClassRepToClassName(kcd,y)]:x in [1..#kch`repOfCl\
        ass],y in [1..#kcd`repOfClass]|IsConjugate(H,KratzerRepToConjClassRep(kch,genh,x),Kratze\
        rRepToConjClassRep(kcd,gend,y))>;
             
        MatchEwD:=<[ConjClassRepToClassName(kce,x),ConjClassRepToClassName(kcd,y)]:x in [1..#kce`repOfCl\
        ass],y in [1..#kcd`repOfClass]|IsConjugate(E,KratzerRepToConjClassRep(kce,gene,x),isoDto\
        DE(KratzerRepToConjClassRep(kcd,gend,y)))>;
        
        FusHwE:=<[x[1],y[1]]:x in MatchHwD,y in MatchEwD|x[2] eq y[2]>; 
//Lemma 3.3
    //(a)
        CHr:=Centralizer(H,rr);
        CHr3:=SylowSubgroup(CHr,3);
        IsNormal(CHr,CHr3);//true
        [x@@fH1:x in CHr3];
        /*
        [ Id(H1p), r^-1, r, c^-1 * r * c * r * s * r * s, r^-1 * c^-1 * r * c * r * s * r * s, r *
        c^-1 * r * c * r * s * r * s, s^-1 * r^-1 * s^-1 * r^-1 * c^-1 * r^-1 * c, r^-1 * s^-1 *
        r^-1 * s^-1 * r^-1 * c^-1 * r^-1 * c, r * s^-1 * r^-1 * s^-1 * r^-1 * c^-1 * r^-1 * c ];
        */
        rrb:=(ss^-1*rr^-1)^2*cc^-1*rr^-1*cc;
        Order(rrb) eq 3;
        rrb in CHr3;
        D1:=Complements(CHr,CHr3)[1];//there is only one
        ll:=(rr*cc)^3;
        Order(ll) eq 4;
        ll in D1;
        ll in Centre(DerivedSubgroup(H));
        [x@@fH1:x in D1];
        /*
        [ Id(H1p), r * c^-1 * r * s * c^-2, (r * c)^3, r * c^2 * s^-1 * r * c^-1 * r^-1 * c^-1, r
        * s * r * c^-2 * s * c^-1 * r^-1 * s^-1, (r^-1 * c^-1)^3, c^2 * s^2 * c * s^-1 * c, (r * s
        * r * s^-1)^2 ];
        */
        ww:=rr* ss * rr * cc^-2 * ss * cc^-1 * rr^-1 * ss^-1;
        Order(ww) eq 2;
    //(b)
        N1:=Normalizer(H,sub<H|rr>);
        nn1:=(ss^-1*cc*(cc^2,ss))^2;
        Order(nn1) eq 2;
        nn1 in N1;
        rr^nn1 eq rr^2;
        rrb^nn1 eq rrb^2;
        nn1 in Centralizer(N1,D1);
    //(c)
        S2:=sub<N1|D1,nn1>;
    //(d)
        R:=sub<CHr|rr,rrb>;
    //(e)
        NHR:=Normalizer(H,R);
        qq1:=ss^3*rr^-1*cc^-1*rr*cc^-1*ss^-1;
        qq2:=(ss^-1)^cc*(cc*rr)^-2;
        Q:=sub<NHR|qq1,qq2>;
        #(Q meet CHr) eq 1;
        NHRf<l,w,q1,q2,r,r1>,fNHR:=FPGroup(sub<NHR|ll,ww,qq1,qq2,rr,rrb>);
        Rf<r,r1>,fR:=FPGroup(R);
        (rr^qq1)@@fR;//r1
        (rrb^qq1)@@fR;//r^-1
        (rr^qq2)@@fR;//r * r1^-1
        (rrb^qq2)@@fR;//r^-1 * r1^-1
//Proposition 3.4
    //(b)
        NGr:=Group<r,r1,n1,w,l,f1|r^3,r1^3,n1^2,l^4,w^2,f1^5,
        (r,r1),(r^-1*n1)^2,
        (r1^-1*n1)^2,(r,l),(r1,l),
        n1*l^-1*n1*l,r^-1*w*r*w,
        r1^-1*w*r1*w,(n1*w)^2,(l^-1*w)^2,
        (r,f1),(r1,f1),
        n1*f1^-1*n1*f1,
        (w*f1^-1)^2,(f1^-1*l^-1)^3,
        l^-2*f1^-1*l^2*f1^-1*l^2*f1^-1,
        l^-1*f1*l^-1*f1^-1*w*l^-1*f1^-2*l*f1>;
        
        NHr:=Group<r,r1,n1,w,l|w^2,n1^2,r^-3,(r,r1),
        r1^-3,l^4,
        (r^-1*n1)^2,
        (r1^-1*n1)^2,(r,l),(r1,l),
        n1*l^-1*n1*l,r^-1*w*r*w,
        r1^-1*w*r1*w,(n1*w)^2,(l^-1*w)^2>;
        
        A6:=Group<l,w,f1|l^4,w^2,f1^5,(l^-1*w)^2,(w*f1^-1)^2,(f1^-1*l^-1)^3,
        l^-2*f1^-1*l^2*f1^-1*l^2*f1^-1,
        l^-1*f1*l^-1*f1^-1*w*l^-1*f1^-2*l*f1>;
        
//Lemma 4.1
    //(a)
        ff:=rr^-1*cc^-1*rr^-1*cc^-2*rr*cc^-1*rr^-1;
        Order(ff) eq 5;
    //(b)
        subh:=Subgroups(H);
        subh:=[x`subgroup:x in subh];
        cand:=[x:x in subh|#x eq 120];
        cand:=[x:x in cand|IsIsomorphic(x,DirectProduct(CyclicGroup(2),Alt(5)))];        
        H1:=cand[1];
        tr:=Transversal(H,Normalizer(H,H1));
        Ar:=sub<H|A,rr>;
        candtr:=[t:t in tr|Ar subset H1^t];
        H1:=H1^candtr[1];
        ff in H1;
    //(c)
        H1f<z,t,u,r,f>,fH1:=FPGroup(sub<H1|zz,tt,uu,rr,ff>);
    //(d)
        E1:=sub<E|rr1,gg>;
        A1:=isoDtoDE(A);
        IsNormal(E1,A1);
        F21:=sub<E1|rr1,rr1^gg>;
    //(e)
        E1f<z,t,u,r,g>,fE1:=FPGroup(sub<E1|[isoDtoDE(x):x in [zz,tt,uu]] cat [rr1,gg]>);
        
    //Proof
        zz1:=isoDtoDE(zz);
        zz1@@fE;
        tt1:=isoDtoDE(tt);
        uu1:=isoDtoDE(uu);
        uu1@@fE;
//Proposition 4.2
    //Proof
        b,hh:=IsConjugate(H,nn1,zz*tt);
        Cn1:=Centralizer(H,nn1);
        candh:=[c*hh:c in Cn1|rr^(c*hh) eq (rr^2,ff)];
        Hf<r,s,f>,fH:=FPGroup(sub<H|rr,ss,ff>);
        [#(x@@fH):x in candh];
        hh:=(ff*rr*ss^2)^2*ss^12;//hh:=candh[#candh];
        hh in candh;
        ww^hh in D;
        Y:=sub<H|ll,ww>;
        Ytohg:=sub<H|[(isoDtoDE(x^hh)^gg)@@isoDtoDE:x in [ll,ww]]>;
        cand2xA6:=[x:x in subh|#x eq 720];
        cand2xA6:=[x:x in cand2xA6|IsIsomorphic(x,DirectProduct(CyclicGroup(2),Alt(6)))]; 
        X:=cand2xA6[1];
        tr:=Transversal(H,Normalizer(H,X));
        candtr:=[t:t in tr|Ytohg subset X^t];
        #candtr eq 2;
        [ff in X^t:t in candtr];//[ false, true ]
        [ff^uu in X^t:t in candtr];//[ true, false ]
        relH1:={Sprint(LHS(r)):r in Relations(H1f)};
        relE1:={Sprint(LHS(r)):r in Relations(E1f)};//I obtain the relations as string and force them into a free group
        F<z,t,u,r,f,g>:=FreeGroup(6);        
        relH1:={ z^2, t^2, u^2, (z * t)^2, (z * u)^2, (t * u)^2, z * r^-1 * z * r, t * r^-1 * u * r,
        r^-3, z * f^-1 * z * f, (t * f^-1)^2, r^-1 * u * t * z * r * u, 
        f^-1 * r^-1 * u * t * f * r^-1, f^-2 * u * t * f^-1 * r^-1 };
        
        relE1:={ z^2, t^2, u^2, (z * t)^2, (z * u)^2, (t * u)^2, z * r^-1 * z * r, t * r^-1 * u * r,
        r^-3, t * g^-1 * z * g, u * g^-1 * u * g, g^-3, g^-1 * t * z * g * z, 
        r^-1 * u * t * z * r * u, r^-1 * g * r^-1 * z * g * r * g^-1 };
        MixedRels:=[((r^2,f)^g,f^u),((r^2,f)^g,f)];
        relJ:=relH1 join relE1 join {MixedRels[1]};
        J:=quo<F|relJ>;
        #J eq 1;
        relJ:=relH1 join relE1 join {MixedRels[2]};
        J:=quo<F|relJ>;
        #J eq 175560;
        pJ,Jp:=CosetAction(J,sub<J|[J.i:i in [1..5]]>);
        CompositionFactors(Jp);
        Jf<r,f,g>,fJ:=FPGroup(sub<Jp|[Jp.i:i in [4..6]]>);
        [LHS(r)^-1:r in Relations(Jf)];
        /*[ r^3, g^3, (r * f)^3, (f^2 * r^-1)^2, f^5, r * g * f * r^-1 * f^-1 * g * r * g, r *
        g^-1 * r^-1 * f * r * f^-1 * g * r^-1 * g^-1, r * g * f^-2 * g^-1 * r^-1 * f * g * r
        * f^-1 * g^-1 * f^-1 ]
        
//Theorem 5.2
    //(b)
        cc@@fH;
    //(c)
        relH:={Sprint(LHS(r)):r in Relations(Hf)};
        relE:={Sprint(LHS(r)):r in Relations(Ef)};
        relJ:={Sprint(LHS(r)):r in Relations(Jf)};
        F<r,s,f,g>:=FreeGroup(4);
        
        relH:={ (r * f^-2)^2, (r * f^-1 * s * f^-1 * s^-1)^2, (s^-1 * f^-1)^4, 
        (r * s^2 * r^-1 * s^-1)^2, (s * f^-1)^4, f * r^-1 * f^-1 * r^-1 * s^-1 * r^-1 * f * r^-1 * f^-1 * s, 
        (r^-1 * s^2 * r * s^-1)^2, f^-5, r^-1 * s * f * r * s^-1 * r^-1 * s * f^2 * s^-1 * f^-1, r^-3, 
        f * r * f^-1 * s^-2 * r^-1 * s^2 * r^-1 * s^-2, s^-1 * f^-1 * s^4 * f^-1 * s^-3, (f^-1 * r^-1)^3 };
        
        relE:={ (g * r^-1 * s^-1)^3, s^-2 * g^-1 * r^-1 * s^-1 * r * s^-2 * r * g, (s * g * s^2)^2,
        (r^-1 * g^-1 * r^-1 * s^-1)^2, (r * s^2 * r^-1 * s^-1)^2, g^-3, 
        s^-1 * r^-1 * g * r^-1 * s^-1 * r * s * g * r^-1 * g^-1, s * r^-1 * s * r^-1 * g^-1 * s^-1 * g^-1, 
        (s * g^-1 * r^-1 * g^-1)^2, r^-3 };
        
        relJ:={ g * r * g^-1 * f * r^-1 * f^-1 * r * g * r^-1, g^-1 * r^-1 * g^-1 * f * r * f^-1 * g^-1 * r^-1, 
        r^-3, f^-5, (r * f^-2)^2, g^-3, (f^-1 * r^-1)^3, f * g * f * r^-1 * g^-1 * f^-1 * r * g * f^2 * g^-1 * r^-1 };
        
        relON:=&join{relH,relE,relJ};
        ON<r,s,f,g>:=quo<F|relON>;        
        /* time consuming
        J:=sub<ON|r,f,g>;
        PJ:=CosetEnumerationProcess(ON,J: CosetLimit := 3000000,Print :=true);
        StartEnumeration(~PJ);
        jho,ONJ:=CosetAction(PJ);
        J1:=jho(J);
        zj:=jho(s^8);
        #[x:x in [1..Degree(ONJ)]|x^zj eq x] eq 1344;
        */
        
        yy:=(ss*cc^2)^3;
        HD:=DerivedSubgroup(H);
        yy in HD;
        H eq sub<H|yy^H>;
        
//Proposition 6.1
        Hbf,fHb:=FPGroup(sub<H|rr,ss,cc>);
        ww@@fHb;
        p1:=s^2 * r^-1 * f^-1 * s^-1 * r^-1 * f^-1 * s^-1;
        p2:=r^-1 * f * s * r^-1 * s * f^-1 * r * s^-1;
        n1:=s * f^-1 * r * s * r^-1 * f * s^2 * r;
        h:=r*f*r;
        x:=r * f^-1 * s * f^-1 * r^-1 * s^-1 * r;
        xb:=r * f^-1 * s * f^-1 * r^-1 * s^-1 * r;
        x1:=x^(g^2*h^(-1));
        a:=p1*p2*p1*x1^-1*p1*x1^-1*n1*p1*p2^-1*x1;
        d:=p2^-1*x1^-1*p1*p2^-1*p1*x1^-1*p1*n1*p2^-1*x1;
        Nor:=func<grp,elt|Normalizer(grp,sub<grp|elt>)>;
        dd:=rho(d);
        N7:=Nor(ONP,dd^4);
        N7 eq sub<N7|rho(a),dd>;
        N7p:=CosetImage(N7,sub<N7|>);
        
    //(g)
        L:=sub<ON|p1,p2,x1,n1>;
        PL:=CosetEnumerationProcess(ON,L: CosetLimit := 400000,Print :=true); 
        StartEnumeration(~PL);        
        rho,ONP:=CosetAction(PL);
        Lp:=rho(L);
        F<p1,p2,x1,n1>:=FreeGroup(4);
        relL:={p1^4,p2^6,x1^3,n1^2,p1^-1*p2^-1*p1^2*p2*p1^-1, p1^-1*n1*p1^2*n1*p1^-1, (p1^-1*n1*p2^-1)^2,
        x1^-1*n1*p1^-2*x1*p1^2*n1,n1*x1^-1*n1*x1^-1*p1^2*x1^-1,x1*n1*x1^-1*p2^-1*p1*p2*n1*p2,
        n1*p2^-3*x1^-1*p2^3*n1*x1^-1,(p2^-1*p1^-1*p2^-1)^3,n1*x1^-1*p2^2*p1^-1*p2^-1*n1*p1*x1,
        x1^-1*p1^-1*x1^-1*p1^-1*x1^-1*p2*x1*p2*x1*p2^-1};
        L<p1,p2,x1,n1>:=quo<F|relL>;
        pL2,L2p:=CosetAction(L,sub<L|[L.x:x in [1,2,4]]>);
    //(h)
        CompositionFactors(L2p);
    //(k)
        t1:=p1*n1*p2^-1*x1*p2^-2*p1*x1^-1*p1^-1*n1;
        t2:=p1*x1*p1*p2^-1*x1*p1*p2*p1*p2^-1*p1^-1*x1;
        t3:=p1*x1*p2^-1*n1*x1^-1*p1*x1^-1*n1*p2*p1;
        t4:=n1*p1*x1*p2^-1*n1*p2*n1*x1*p1*x1^-1;
        t5:=p2^-1*n1*p1*x1*p1*p2*p1*x1*p2^-1*n1;
        t6:=x1*p2*n1*p1*x1^-1*p1*x1*p2*p1^-1*n1;
        T:=sub<L2p|[pL2(x):x in [t1,t2,t3,t4,t5,t6]]>;
        #Core(L2p,T) eq 1;
        Index(L2p,T) eq 456;
    //(d)
        a:=p1*p2*p1*x1^-1*p1*x1^-1*n1*p1*p2^-1*x1;
        d:=p2^-1*x1^-1*p1*p2^-1*p1*x1^-1*p1*n1*p2^-1*x1;
        R:=sub<L2p|[pL2(x):x in [a,d]]>;
        R7:=SylowSubgroup(R,7);
        Exponent(R7) eq 7;
        IsAbelian(R7); 
        b,K:=HasComplement(R,R7);
        IsNilpotent(K);
        K2:=SylowSubgroup(K,2);
        not IsAbelian(K2);
        #[x:x in K2|Order(x) eq 2] eq 5;
        b:=IsIsomorphic(R,N7p);
    //(a)   
        a1:=r*f*r^-1*s^-4*r;
        d1:=g^-1*r*f^-1*r^-1*f*g;
        q1:=s^-1*g*r*s^2*r^-1*g;
        N5 eq sub<N5|[rho(x):x in [a1,d1,q1]]>;
        
//Corollary 6.4
    w:=s*g*r^3*g*r^7*f*s*f*s*r^7*g^2*r^3*f*g*f;
    b:=((r*s^2)^3)^w;
    z:=s^8;
    ww:=rho(w);
    bb:=rho(b);
    zz:=rho(s^8);
    L2:=sub<ONP|[rho(x):x in [b*z*b^-1, (z*b^2)^-2*b^3*(z*b^2)^2]]>;
    L3:=sub<ONP|[rho(x):x in [b^-1*z*b, (z*b^2)^-2*b*(z*b^2)^2]]>;
    bo:=IsConjugate(ONP,Lp,L3);